Quick sort

[lehang_gb1]

Nêu ý tưởng và viết chương trình sắp xếp dãy số nguyên theo kiểu Quick Sort(sắp xếp nhanh)

[Farmer_Boy]

cái này bạn cần hỏi hay đánh đố người khác????????

[raicars]

bài bạn cần tìm đây =>
http://pascalvn.com/showthread.php?tid=14&pid=36#pid36

[lehang_gb1]

{Sap xep nhanh Quick sort}
 
type mang=array[1..100] of integer;
Var A:mang;
i,N,x:integer;
procedure phandoan(l,r:integer);
Var i,j,x,w:integer;
Begin
x:=A[(l+r) div 2];
  i:=l;j:=r;
  Repeat
    While(a[i]<x) do i:=i+1;
     While (x<a[j]) do j:=j-1;
      If i<=j then
        Begin
          w:=a[i];a[i]:=a[j];a[j]:=w;
          i:=i+1;j:=j-1;
        End;
 until i>j;
 If l<j then phandoan(l,j);
 If i<r then phandoan(i,r);
End;
BEGIN
write('Nhap vao so phan tu cua mang:');Readln(N);
For i:=1 to N do
 begin
   write('A[',i,']=');
   Readln(A[i]);
 End;
phandoan(1,N);
  For i:=1 to N do write(A[i]:3);
 Readln
End.

[auauau97]

đây là code sắp xếp nhanh trong phần VD của turbo pascal, bạn xem thử nhá:

{************************************************}
{                                                }
{ QuickSort Demo                                 }
{ Copyright (c) 1985,90 by Borland International }
{                                                }
{************************************************}

program QSort;
{$R-,S-}
uses Crt;

{ This program demonstrates the quicksort algorithm, which      }
{ provides an extremely efficient method of sorting arrays in   }
{ memory. The program generates a list of 1000 random numbers   }
{ between 0 and 29999, and then sorts them using the QUICKSORT  }
{ procedure. Finally, the sorted list is output on the screen.  }
{ Note that stack and range checks are turned off (through the  }
{ compiler directive above) to optimize execution speed.        }

const
  Max = 1000;

type
  List = array[1..Max] of Integer;

var
  Data: List;
  I: Integer;

{ QUICKSORT sorts elements in the array A with indices between  }
{ LO and HI (both inclusive). Note that the QUICKSORT proce-    }
{ dure provides only an "interface" to the program. The actual  }
{ processing takes place in the SORT procedure, which executes  }
{ itself recursively.                                           }

procedure QuickSort(var A: List; Lo, Hi: Integer);

procedure Sort(l, r: Integer);
var
  i, j, x, y: integer;
begin
  i := l; j := r; x := a[(l+r) DIV 2];
  repeat
    while a[i] < x do i := i + 1;
    while x < a[j] do j := j - 1;
    if i <= j then
    begin
      y := a[i]; a[i] := a[j]; a[j] := y;
      i := i + 1; j := j - 1;
    end;
  until i > j;
  if l < j then Sort(l, j);
  if i < r then Sort(i, r);
end;

begin {QuickSort};
  Sort(Lo,Hi);
end;

begin {QSort}
  Write('Now generating 1000 random numbers...');
  Randomize;
  for i := 1 to Max do Data[i] := Random(30000);
  Writeln;
  Write('Now sorting random numbers...');
  QuickSort(Data, 1, Max);
  Writeln;
  for i := 1 to 1000 do Write(Data[i]:8);
end.

[AVATARBLACK]

cái này bạn cần hỏi hay đánh đố người khác????????

Bạn ấy đánh đố người khác thì các Vị mách nước cho bạn đó làm gì!!